Cálculos con reconocimiento de nivel - RICOH Predictive Insight™

Funciones de cálculo con reconocimiento de nivel de agregado (LAC-A)

Con las funciones LAC-A, puede especificar en qué nivel agrupar el cálculo. Añadiendo un argumento a una función de agregación existente, como sum, max o count, puede definir un nivel de agrupación para la agregación. El nivel añadido puede ser cualquier dimensión independiente de las dimensiones añadidas al elemento visual. Por ejemplo: sum(measure,[group_field_A]).

Para utilizar funciones LAC-A, introdúzcalas directamente en el editor, añadiendo los niveles de agregación como segundo argumento, entre paréntesis. Este ejemplo muestra una función de agregación y una función LAC-A, a modo de comparación:

Función de agregación: sum({Printed Pages})
Función LAC-A: sum({Printed Pages}, [{Location Name},{Printer Name}])

Los resultados de LAC-A se calculan con el nivel especificado entre paréntesis y pueden utilizarse como operando de una función de agregación.

También puede crear una clave de grupo LAC dinámica que se adapte a los campos de agrupación del elemento visual utilizando el parámetro $visualDimensions. El parámetro $visualDimensions representa los campos añadidos al contenedor del campo Agrupar por en el elemento visual actual. Estos ejemplos muestran cómo añadir dinámicamente claves de grupo a las dimensiones del elemento visual o cómo eliminarlas:

LAC-A con clave de grupo añadida dinámicamente: sum({Printed Pages}, [${visualDimensions},{Location Name},{Printer Name}])
Esta función calcula, antes de que se calcule la agregación a nivel del elemento visual, la suma de páginas impresas, agrupando por ubicación, impresora y cualquier otro campo del contenedor del campo Agrupar por.
LAC-A con clave de grupo añadida dinámicamente: sum({Printed Pages}, [${visualDimensions},!{Location Name},!{Printer Name}])
Esta función calcula, antes de que se calcule la agregación a nivel del elemento visual, la suma de páginas impresas, agrupando por los campos del contenedor del campo Agrupar por, excepto ubicación e impresora.

Puede especificar una clave de grupo añadida o una clave de grupo eliminada en una expresión LAC, pero no ambas.

Las funciones LAC-A son compatibles con las siguientes funciones de agregación: avg, count, distinct_count, max, median, min, percentile, percentileCont, percentileDisc, stdev, stdevp, sum, var y varp.

Ejemplos de LAC-A

Puede utilizar las funciones LAC-A para este tipo de casos prácticos:

Realizar cálculos independientes de los niveles del elemento visual. Por ejemplo, si utiliza el siguiente cálculo, las páginas impresas se agregan solo al nivel de ubicación, pero no en el resto de dimensiones del elemento visual.
```
sum({Printed Pages},[{Location Name}])
```
Realizar cálculos para dimensiones no incluidas en el elemento visual. Por ejemplo, si utiliza la siguiente función, podrá calcular el promedio de páginas impresas por ubicación, aunque el campo Nombre de la ubicación no esté incluido en el elemento visual.
```
avg(sum({Printed Pages},[{Location Name}]))
```
Utilice LAC-A combinada con otras funciones de agregación y funciones LAC-W. Hay dos maneras de anidar funciones LAC-A con otras funciones.
- Puede escribir una sintaxis anidada al crear un cálculo. Por ejemplo, la función LAC-A puede anidarse con una función LAC-W:
```
sum(avgOver({Printed Copies},[{Printer Name}],PRE_AGG),[{Location Name}])
```
- Cuando añade una función LAC-A a un elemento visual, el cálculo puede combinarse con las funciones de agregación a nivel del elemento visual que haya establecido en los contenedores de campo. Para obtener más información sobre cómo cambiar la agregación de campos en el elemento visual, consulte Modificación de la agregación a campos.

Limitaciones de LAC-A

Estas limitaciones se aplican a las funciones LAC-A:

Las funciones LAC-A son compatibles con todas las funciones de agregación aditivas y no aditivas, como sum, count y percentile. Las funciones LAC-A no son compatibles con las funciones de agregación condicional que terminan en if, como sumif y countif, ni con las funciones de agregación de período que empiezan por periodToDate, como periodToDateSum y periodToDateMax.
Los totales a nivel de fila y columna no son compatibles con las funciones LAC-A en tablas y tablas dinámicas. Cuando se añaden totales a nivel de fila o columna al gráfico, el número total aparece en blanco. Las demás dimensiones no LAC no se ven afectadas.
Actualmente no se admiten funciones LAC-A anidadas. Se admite una capacidad limitada de funciones LAC-A anidadas con funciones de agregación regulares y funciones LAC-W. Por ejemplo, estas funciones son válidas:
- Aggregation(LAC-A()). Por ejemplo: max(sum({Printed Pages}, [{Location Name}]))
- LAC-A(LAC-W()). Por ejemplo: sum(sumOver({Printed Pages},[{Printer Name}],PRE_AGG), [{Location Name}])
Estas funciones no son válidas:
- LAC-A(Aggregation()). Por ejemplo: sum(max({Printed Pages}), [{Location Name}])
- LAC-A(LAC-A()). Por ejemplo: sum(max({Printed Pages}, [{Location Name}]),[{Printer Type}])
- LAC-W(LAC-A()). Por ejemplo: sumOver(sum({Printed Pages},[{Printer Name}]),[{Location Name}],PRE_AGG)

Funciones de cálculo con reconocimiento de nivel de ventana (LAC-W)

Con las funciones LAC-W, puede especificar la ventana o partición para realizar el cálculo. Las funciones LAC-W son un grupo de funciones de ventana, como sumOver, maxOver o denseRank, que se pueden ejecutar a nivel de prefiltro o preagregación. Por ejemplo: sumOver(measure,[partition_field_A],pre_agg).

Las funciones de LAC-W pueden ayudarle a responder este tipo de preguntas:

¿Cuántas de las impresoras han procesado un número de trabajos inferior a un valor determinado? El recuento se utiliza como dimensión y no como métrica en el elemento visual.
¿Cuál es la contribución de cada impresora a la productividad total del sistema de impresión?
¿Cómo se agrupan mis impresoras en rangos de productividad acumulada? La agrupación se utiliza como dimensión y no como métrica.

Para preguntas más complejas, puede inyectar un cálculo o filtro antes de que RICOH Predictive Insight llegue a un punto específico de la evaluación de sus ajustes. Para influir directamente en los resultados, añada una palabra clave de nivel de cálculo a un cálculo de tabla. Para obtener más información sobre cómo se evalúan las consultas, vea Orden de evaluación en los análisis.

Estos niveles de cálculo son compatibles con las funciones LAC-W:

PRE_FILTER: antes de aplicar los filtros del análisis, RICOH Predictive Insight evalúa los cálculos del prefiltro. A continuación, aplica cualquier filtro configurado sobre los cálculos del prefiltro.
PRE_AGG: antes de calcular las agregaciones a nivel del elemento visual, RICOH Predictive Insight realiza los cálculos de preagregación. A continuación, aplica cualquier filtro configurado sobre los cálculos de preagregación Estas operaciones se realizan antes de aplicar los filtros N superiores e inferiores.

Puede utilizar la palabra clave PRE_FILTER o PRE_AGG como parámetro en estas funciones de cálculo de tablas: avgOver, countOver, denseRank, distinctCountOver, minOver, maxOver, percentileRank, Rank, stdevOver, stdevpOver, sumOver, varOver y varpOver.

Cuando se especifica un nivel de cálculo, se utiliza una medida no agregada en la función. Por ejemplo, puede utilizar countOver({Job ID}, [{Printer ID}], PRE_AGG). Al utilizar PRE_AGG, se especifica que la función countOver se ejecute en el nivel de preagregación.

Por defecto, el primer parámetro de cada función debe ser una medida agregada. Si utiliza PRE_FILTER o PRE_AGG, utilizará una medida no agregada para el primer parámetro.

Para las funciones LAC-W, la agregación visual por defecto es MIN para eliminar duplicados. Para cambiar la agregación, haga clic en botónOpciones , el botón Opciones, situado junto al campo, y seleccione Agregar y una de las funciones de agregación disponibles.